Flash CS4 Professional ActionScript 2.0

Función getURL

getURL(url:String, [window:String, [method:String]]) : Void

Carga un documento de una URL específica en una ventana o pasa variables a otra aplicación en una URL definida. Para probar esta función, asegúrese de que el archivo que se va a cargar se encuentra en la ubicación especificada. Para utilizar una URL absoluta (por ejemplo, http://www.myserver.com), se necesita una conexión de red.

Nota de seguridad: en Flash Player 8 y versiones posteriores (para la ejecución de contenido local en un navegador), las llamadas a la función getURL() que especifican el pseudoprotocolo "javascript:" (por ejemplo, getURL("javascript:someFunction()")) sólo están permitidas si el archivo SWF y la página Web que lo contiene (si existe) se encuentran en la libre configuración local de seguridad de confianza.

Nota de seguridad: en Flash Player 9 y versiones posteriores, si el código de un archivo SWF que se esté ejecutando la libre configuración local con acceso al sistema de archivos llama a la función getURL() y especifica un nombre de ventana personalizado para el parámetro window, el nombre de la ventana se transferirá a un nombre aleatorio. El nombre tiene la forma "_flashXXXXXXXX", donde cada X representa un dígito hexadecimal aleatorio. Dentro de la misma sesión (hasta cerrar la ventana del navegador), si se vuelve a llamar a la función y se especifica el mismo nombre para el parámetro window, se utilizará la misma cadena aleatoria.

Disponibilidad: ActionScript 1.0; Flash Player 2 - Las opciones GET y POST sólo están disponibles en Flash Player 4 y versiones posteriores.

Parámetros

url: String - URL del cual se obtiene el documento.

window: String [opcional] - Especifica la ventana o marco HTML donde debería cargarse el documento. Puede introducir el nombre de una ventana específica o seleccionarlo de entre los siguientes nombres de destino reservados:

  • _self especifica el fotograma actual en la ventana actual.
  • _blank especifica una nueva ventana.
  • _parent especifica el elemento principal del fotograma actual.
  • _top especifica el fotograma de nivel superior de la ventana actual.

method: String [opcional] - Un método GET o POST para enviar variables. Si no hay ninguna variable, omita este parámetro. El método GET añade las variables al final de la URL y se utiliza para números reducidos de variables. El método POST envía las variables en un encabezado HTTP independiente y se utiliza para enviar cadenas de variables largas.

Ejemplo

Este ejemplo carga una imagen en un clip de película. Cuando se hace clic en la imagen, se carga un nuevo URL en una nueva ventana del navegador.

var listenerObject:Object = new Object();
listenerObject.onLoadInit = function(target_mc:MovieClip) {
 target_mc.onRelease = function() {
 getURL("http://www.adobe.com/software/flash/flashpro/", "_blank");
 };
};
var logo:MovieClipLoader = new MovieClipLoader();
logo.addListener(listenerObject);
logo.loadClip("http://www.helpexamples.com/flash/images/image1.jpg",
 this.createEmptyMovieClip("adobe_mc", this.getNextHighestDepth()));

En el ejemplo siguiente, se utiliza getURL() para enviar un mensaje de correo electrónico:

myBtn_btn.onRelease = function(){
 getURL("mailto:you@somedomain.com");
};

En el código ActionScript siguiente, se utiliza JavaScript para abrir una ventana de alerta cuando el archivo SWF se incorpora en una ventana del navegador (recuerde que cuando se llama a JavaScript con getURL(), el parámetro url tiene un límite de 508 caracteres):

myBtn_btn.onRelease = function(){
 getURL("javascript:alert('you clicked me')");
};

También puede utilizar GET o POST para enviar variables. El ejemplo siguiente utiliza GET para añadir variables a una URL:

var firstName:String = "Gus";
var lastName:String = "Richardson";
var age:Number = 92;
myBtn_btn.onRelease = function(){
 getURL("http://www.adobe.com", "_blank", "GET");
};

El código ActionScript siguiente utiliza POST para enviar variables en el encabezado HTTP. Compruebe los documentos en una ventana del navegador. En caso contrario, las variables se enviarán utilizando GET:

var firstName:String = "Gus";
var lastName:String = "Richardson";
var age:Number = 92;
getURL("http://www.adobe.com", "_blank", "POST");

Véase también

Función loadVariables, send (método XML.send), sendAndLoad (método XML.sendAndLoad)