new XMLSocket(streamOrFlash)

Creates a new XMLSocket object ("flash") or a new XMLStreams object ("stream"). The XMLSocket and XMLStreams objects are not initially connected to any server. You must call XMLSocket.connect() to connect the object to a server.

For more information about the XMLStreams class, see XMLStreams class.

var socket = new XMLSocket("flash");

var stream = new XMLSocket("stream");

myXMLSocket.close()

Closes the connection specified by the XMLSocket object.

var socket = new XMLSocket(); 
socket.connect(null, 2000); 
socket.close();

myXMLSocket.connect(host, port)

Establishes a connection to the specified Internet host by using the specified TCP port (must be 1024 or higher), and returns true or false, depending on whether a connection is successfully established. If you don’t know the port number of the Internet host computer, contact your network administrator.

If you specify null for the host parameter, the local host is contacted.

The Server-Side ActionScript XMLSocket.connect() method can connect to computers that are not in the same domain as the SWF file.

If XMLSocket.connect() returns a value of true, the initial stage of the connection process is successful. Later, the XMLSocket.onConnect() handler is invoked to determine whether the final connection succeeded or failed. If XMLSocket.connect() returns false, a connection could not be established.

var socket = new XMLSocket() 
socket.onConnect = function (success) { 
    if (success) { 
        trace ("Connection succeeded!") 
    } else { 
        trace ("Connection failed!") 
    } 
}; 
if (!socket.connect(null, 2000)) { 
    trace ("Connection failed!") 
}

myXMLSocket.maxUnprocessedChars

The number of characters the connection can receive from the XML server without receiving an end tag or the XMLSocket connection closes. The value of XMLSocket.maxUnprocessedChars can be -1 or any value greater than 0. The value -1 means that an unlimited amount of data can be processed. However, the value of maxUnprocessedChars cannot exceed the value specified in the Application.xml file. The default value in the Application.xml file is 4096 bytes.

Setting this property in a server-side script overrides the value of the MaxUnprocessedChars element in the Application.xml file for each XMLSocket object. If the property is not set in a server-side script, the server uses the value set in the MaxUnprocessedChars element of the Application.xml file.

myXMLSocket.onClose = function() {}

Invoked when an open connection is closed by the server. The default implementation of this method performs no actions. To override the default implementation, you must assign a function containing custom actions.

var socket = new XMLSocket(); 
socket.connect(null, 2000); 
socket.onClose = function () { 
    trace("Connection to server lost."); 
}

myXMLSocket.onConnect = function(success) {}

Invoked by Flash Media Interactive Server when a connection request initiated through XMLSocket.connect() succeeds or fails. If the connection succeeded, the success parameter is true; otherwise, false.

The default implementation of this method performs no actions. To override the default implementation, you must assign a function containing custom actions.

socket = new XMLSocket(); 
socket.onConnect = myOnConnect; 
 
socket.connect(null,2000); 
 
function myOnConnect(success) { 
    if (success) { 
        trace("Connection success") 
    } else { 
        trace("Connection failed") 
    } 
}

myXMLSocket.onData = function(src) {}

Invoked when a message has been downloaded from the server, terminated by a zero (0) byte. You can override XMLSocket.onData() to intercept the data sent by the server without parsing it as XML. This is useful if you’re transmitting arbitrarily formatted data packets and you would prefer to manipulate the data directly when it arrives, rather than have Flash Media Interactive Server parse the data as XML.

By default, the XMLSocket.onData() method invokes the XMLSocket.onXML() method. If you override XMLSocket.onData() with custom behavior, XMLSocket.onXML() is not called unless you call it in your implementation of XMLSocket.onData().

XMLSocket.prototype.onData = function (src) { 
    this.onXML(new XML(src)); 
}

myXMLSocket.onXML = function(object) {}

Invoked when the specified XML object containing an XML document arrives through an open XMLSocket connection. An XMLSocket connection can be used to transfer an unlimited number of XML documents between the client and the server. Each document is terminated with a zero (0) byte. When Flash Media Interactive Server receives the zero byte, it parses all of the XML received since the previous zero byte or, if this is the first message received, since the connection was established. Each batch of parsed XML is treated as a single XML document and passed to the onXML() handler.

The default implementation of this method performs no actions. To override the default implementation, you must assign a function containing actions that you define.

<MESSAGE USER="John" TEXT="Hello, my name is John!" />.  
var socket = new XMLSocket();

socket.onXML = function (doc) { 
    var e = doc.firstChild; 
    if (e != null && e.nodeName == "MESSAGE") { 
        displayMessage(e.attributes.user, e.attributes.text); 
    } 
};

myXMLSocket.send(object)

Converts the XML object or data specified in the object parameter to a string and transmits it to the server, followed by a zero (0) byte. If object is an XML object, the string is the XML textual representation of the XML object.

If the myXMLSocket object is not connected to the server (by using XMLSocket.connect()), the XMLSocket.send() operation fails.

var myXMLSocket = new XMLSocket(); 
var my_xml = new XML(); 
var myLogin = my_xml.createElement("login"); 
myLogin.attributes.username = usernameTextField; 
myLogin.attributes.password = passwordTextField; 
my_xml.appendChild(myLogin); 
myXMLSocket.send(my_xml);