XML class

Availability

Flash Media Server 2

Parameters

source

A string; the XML text to parse to create the new XML object.

Returns

A reference to an XML object.

Example

The following example creates a new, empty XML object:

var my_xml = new XML();

The following example creates an XML object by parsing the XML text specified in the source parameter and populates the newly created XML object with the resulting XML document tree:

var other_xml = new XML("<state name=\"California\"><city>San Francisco</city></state>");

See also

XML.createElement(), XML.createTextNode()

Availability

Flash Media Server 2

Parameters

headerName

A string representing an HTTP request header name.

headerValue

A string representing the value associated with headerName.

Example

The following example adds a custom HTTP header named SOAPAction with a value of Foo to an XML object named my_xml:

my_xml.addRequestHeader("SOAPAction", "'Foo'");

The following example creates an array named headers that contains two alternating HTTP headers and their associated values. The array is passed as a parameter to the addRequestHeader() method.

var headers = new Array("Content-Type", "text/plain", "X-ClientAppVersion", "2.0"); 
my_xml.addRequestHeader(headers);

Availability

Flash Media Server 2

Parameters

childNode

An XMLNode object that represents the node to be moved from its current location to the child list of the my_xml object.

Returns

A boolean value; true if successful; otherwise, false.

Example

The following example performs these actions:

1. Creates two empty XML documents, doc1 and doc2.

2. Creates a new node, by using the createElement() method, and appends it, by using the appendChild() method, to the XML document named doc1.

3. Shows how to move a node by using the appendChild() method, by moving the root node from doc1 to doc2.

4. Clones the root node from doc2 and appends it to doc1.

5. Creates a new node and appends it to the root node of the XML document doc1.

var doc1 = new XML(); 
var doc2 = new XML(); 
 
// Create a root node and add it to doc1. 
var rootnode = doc1.createElement("root"); 
doc1.appendChild(rootnode); 
trace ("doc1: " + doc1); // output: doc1: <root /> 
trace ("doc2: " + doc2); // output: doc2: 
 
// Move the root node to doc2. 
doc2.appendChild(rootnode); 
trace ("doc1: " + doc1); // output: doc1: 
trace ("doc2: " + doc2); // output: doc2: <root /> 
 
// Clone the root node and append it to doc1. 
var clone = doc2.firstChild.cloneNode(true); 
doc1.appendChild(clone); 
trace ("doc1: " + doc1); // output: doc1: <root /> 
trace ("doc2: " + doc2); // output: doc2: <root /> 
 
// Create a new node to append to root node (named clone) of doc1. 
var newNode = doc1.createElement("newbie"); 
clone.appendChild(newNode); 
trace ("doc1: " + doc1); // output: doc1: <root><newbie /></root>

Availability

Flash Media Server 2

Example

The following example shows the XML attribute names:

// Create a tag called 'mytag' with  
// an attribute called 'name' with value 'Val'. 
var doc = new XML("<mytag name=\"Val\"> item </mytag>"); 
 
// Assign the value of the 'name' attribute to variable y. 
var y = doc.firstChild.attributes.name; 
trace (y);// output: Val 
 
// Create a new attribute named 'order' with value 'first'. 
doc.firstChild.attributes.order = "first"; 
 
// Assign the value of the 'order' attribute to variable z. 
var z = doc.firstChild.attributes.order 
trace(z);// output: first

Availability

Flash Media Server 2

Example

The following example shows how to use the XML.childNodes property to return an array of child nodes:

// Create a new XML document. 
var doc = new XML(); 
 
// Create a root node. 
var rootNode = doc.createElement("rootNode"); 
 
// Create three child nodes. 
var oldest = doc.createElement("oldest"); 
var middle = doc.createElement("middle"); 
var youngest = doc.createElement("youngest"); 
 
// Add the rootNode as the root of the XML document tree. 
doc.appendChild(rootNode); 
 
// Add each of the child nodes as children of rootNode. 
rootNode.appendChild(oldest); 
rootNode.appendChild(middle); 
rootNode.appendChild(youngest); 
 
// Create an array and use rootNode to populate it. 
var firstArray:Array = doc.childNodes; 
trace (firstArray);  
// Output: <rootNode><oldest /><middle /><youngest /></rootNode> 
 
// Create another array and use the child nodes to populate it. 
var secondArray = rootNode.childNodes; 
trace(secondArray);  
// Output: <oldest />,<middle />,<youngest />

See also

XML.nodeType

Availability

Flash Media Server 2

Parameters

deep

A boolean value; if set to true, the children of the specified XML object will be recursively cloned; otherwise, false.

Returns

An XMLNode object.

Example

The following example shows how to use the XML.cloneNode() method to create a copy of a node:

// Create a new XML document. 
var doc = new XML(); 
 
// Create a root node. 
var rootNode = doc.createElement("rootNode"); 
 
// Create three child nodes. 
var oldest = doc.createElement("oldest"); 
var middle = doc.createElement("middle"); 
var youngest = doc.createElement("youngest"); 
 
// Add the rootNode as the root of the XML document tree. 
doc.appendChild(rootNode); 
 
// Add each of the child nodes as children of rootNode. 
rootNode.appendChild(oldest); 
rootNode.appendChild(middle); 
rootNode.appendChild(youngest); 
 
// Create a copy of the middle node by using cloneNode(). 
var middle2 = middle.cloneNode(false); 
 
// Insert the clone node into rootNode between  
// the middle and youngest nodes. 
rootNode.insertBefore(middle2, youngest); 
trace(rootNode); 
// Output (with line breaks added):  
// <rootNode> 
//<oldest /> 
//<middle /> 
//<middle /> 
//<youngest /> 
// </rootNode> 
 
// Create a copy of rootNode by using cloneNode() to demonstrate a deep copy. 
var rootClone = rootNode.cloneNode(true); 
 
// Insert the clone, which contains all child nodes, to rootNode. 
rootNode.appendChild(rootClone); 
trace(rootNode);  
// Output (with line breaks added):  
// <rootNode> 
// <oldest/> 
// <middle/> 
// <middle/> 
// <youngest/> 
// <rootNode> 
//<oldest/> 
//<middle/> 
//<middle/> 
//<youngest/> 
// </rootNode> 
// </rootNode>

Availability

Flash Media Server 2

Example

The following example creates a new XML document and checks its default content type:

// Create a new XML document. 
var doc = new XML(); 
 
// Trace the default content type. 
trace(doc.contentType); 
 
// output: application/x-www-form-urlencoded

Availability

Flash Media Server 2

Parameters

name

A string indicating the tag name of the XML element being created.

Returns

An XML node; an XML element.

Example

The following example creates three XMLNode objects by using the createElement() method:

// Create an XML document. 
var doc = new XML(); 
 
// Create three XML nodes by using createElement(). 
var element1 = doc.createElement("element1"); 
var element2 = doc.createElement("element2"); 
var element3 = doc.createElement("element3"); 
 
// Place the new nodes into the XML tree. 
doc.appendChild(element1); 
element1.appendChild(element2); 
element1.appendChild(element3); 
 
trace(doc); 
// Output: <element1><element2 /><element3 /></element1>

See also

XML.createTextNode()

Availability

Flash Media Server 2

Parameters

text

A string; the text used to create the new text node.

Returns

An XML node.

Example

The following example creates two XML text nodes by using the createTextNode() method and places them into existing XML nodes:

// Create an XML document. 
var doc = new XML(); 
 
// Create three XML nodes by using createElement(). 
var element1 = doc.createElement("element1"); 
var element2 = doc.createElement("element2"); 
var element3 = doc.createElement("element3"); 
 
// Place the new nodes into the XML tree. 
doc.appendChild(element1); 
element1.appendChild(element2); 
element1.appendChild(element3); 
 
// Create two XML text nodes by using createTextNode(). 
var textNode1 = doc.createTextNode("textNode1"); 
var textNode2 = doc.createTextNode("textNode2"); 
 
// Place the new nodes into the XML tree. 
element2.appendChild(textNode1); 
element3.appendChild(textNode2); 
 
trace(doc); 
// Output (with line breaks added between tags): 
// <element1> 
//<element2>textNode1</element2> 
//<element3>textNode2</element3> 
// </element1>

See also

XML.createElement()

Availability

Flash Media Server 2

Example

The following example uses the XML.docTypeDecl property to set the DOCTYPE declaration for an XML object:

my_xml.docTypeDecl = "<!DOCTYPE greeting SYSTEM \"hello.dtd\">";

Availability

Flash Media Server 2

Example

The following example shows how to use XML.firstChild to loop through a node’s child nodes:

// Create a new XML document. 
var doc = new XML(); 
 
// Create a root node. 
var rootNode = doc.createElement("rootNode"); 
 
// Create three child nodes. 
var oldest = doc.createElement("oldest"); 
var middle = doc.createElement("middle"); 
var youngest = doc.createElement("youngest"); 
 
// Add the rootNode as the root of the XML document tree. 
doc.appendChild(rootNode); 
 
// Add each of the child nodes as children of rootNode. 
rootNode.appendChild(oldest); 
rootNode.appendChild(middle); 
rootNode.appendChild(youngest); 
 
// Use firstChild to iterate through the child nodes of rootNode. 
for (var aNode = rootNode.firstChild; aNode != null; aNode = aNode.nextSibling) { 
    trace(aNode); 
} 
 
// Output: 
// <oldest /> 
// <middle /> 
// <youngest />

Availability

Flash Media Server 2

Returns

A number.

See also

XML.getBytesTotal()

Availability

Flash Media Server 2

Returns

A number.

See also

XML.getBytesLoaded()

Availability

Flash Media Server 2

Parameters

prefix

A string; the prefix for which the method returns the associated namespace.

Returns

A string.

Example

The following example creates a very simple XML object and outputs the result of a call to getNamespaceForPrefix():

function createXML() { 
    var str = "<Outer xmlns:exu=\"http://www.example.com/util\">" + "<exu:Child id='1' />" + "<exu:Child id='2' />" + "<exu:Child id='3' />" + "</Outer>"; 
    return new XML(str).firstChild; 
} 
 
var xml = createXML(); 
trace(xml.getNamespaceForPrefix("exu")); // output: http://www.example.com/util 
trace(xml.getNamespaceForPrefix("")); // output: null

See also

XML.getPrefixForNamespace()

Availability

Flash Media Server 2

Parameters

nsURI

A string; the namespace URI for which the method returns the associated prefix.

Returns

A string.

Example

The following example creates a very simple XML object and outputs the result of a call to the getPrefixForNamespace() method. The Outer XML node, which is represented by the xmlDoc variable, defines a namespace URI and assigns it to the exu prefix. Calling the getPrefixForNamespace() method with the defined namespace URI ("http://www.example.com/util") returns the prefix exu, but calling this method with an undefined URI ("http://www.example.com/other") returns null. The first exu:Child node, which is represented by the child1 variable, also defines a namespace URI ("http://www.example.com/child"), but does not assign it to a prefix. Calling this method on the defined, but unassigned, namespace URI returns an empty string.

function createXML() { 
    var str = "<Outer xmlns:exu=\"http://www.example.com/util\">" 
+ "<exu:Child id='1' xmlns=\"http://www.example.com/child\"/>" 
+ "<exu:Child id='2' />" 
+ "<exu:Child id='3' />" 
+ "</Outer>"; 
    return new XML(str).firstChild; 
} 
 
var xmlDoc = createXML(); 
trace(xmlDoc.getPrefixForNamespace("http://www.example.com/util")); // output: exu 
trace(xmlDoc.getPrefixForNamespace("http://www.example.com/other")); // output: null 
 
var child1 = xmlDoc.firstChild; 
trace(child1.getPrefixForNamespace("http://www.example.com/child")); // output: [empty string] 
trace(child1.getPrefixForNamespace("http://www.example.com/other")); // output: null

See also

XML.getNamespaceForPrefix()

Availability

Flash Media Server 2

Returns

A boolean value.

Example

The following example creates a new XML packet. If the root node has child nodes, the code loops over each child node to display the name and value of the node.

var my_xml = new XML("<login><username>hank</username><password>rudolph</password></login>"); 
if (my_xml.firstChild.hasChildNodes()) { 
    // Use firstChild to iterate through the child nodes of rootNode. 
    for (var aNode = my_xml.firstChild.firstChild; aNode != null; aNode=aNode.nextSibling) { 
        if (aNode.nodeType == 1) { 
            trace(aNode.nodeName+":\t"+aNode.firstChild.nodeValue); 
        } 
    } 
}

The following output appears:

username:hank 
password:rudolph

Availability

Flash Media Server 2

Example

The following example loads an XML file with a text node that contains only white space; the foyer tag contains 14 space characters. To run this example, create a text file named flooring.xml and copy the following tags into it:

<house> 
    <kitchen> ceramic tile </kitchen> 
    <bathroom> linoleum </bathroom> 
    <foyer></foyer> 
</house>

The following is the server-side code:

// Create a new XML object. 
var flooring = new XML(); 
 
// Set the ignoreWhite property to true (the default value is false). 
flooring.ignoreWhite = true; 
 
// After loading is complete, trace the XML object. 
flooring.onLoad = function(success) { 
    trace(flooring); 
} 
 
// Load the XML into the flooring object. 
flooring.load("flooring.xml"); 
 
/* output (line breaks added for clarity): 
<house> 
<kitchen>ceramic tile</kitchen> 
<bathroom>linoleum</bathroom> 
</foyer> 
</house> 
*/

If you change the setting of flooring.ignoreWhite to false, or simply remove that line of code entirely, the 14 space characters in the foyer tag are preserved:

... 
// Set the ignoreWhite property to false (the default value). 
flooring.ignoreWhite = false; 
... 
/* output (line breaks added for clarity): 
<house> 
    <kitchen> ceramic tile </kitchen> 
    <bathroom>linoleum</bathroom> 
    <foyer></foyer> 
</house> 
*/

Availability

Flash Media Server 2

Parameters

childNode

The XMLNode object to be inserted.

beforeNode

The XMLNode object before the insertion point for the childNode node.

Returns

A boolean value; true if successful; otherwise, false.

Example

The following example is an excerpt from the XML.cloneNode() example:

// Create a copy of the middle node by using cloneNode(). 
var middle2 = middle.cloneNode(false); 
 
// Insert the clone node into rootNode  
// between the middle and youngest nodes. 
rootNode.insertBefore(middle2, youngest);

Availability

Flash Media Server 2

Example

The following example uses the XML.lastChild property to iterate through the child nodes of an XMLNode object, starting with the last item in the node’s child list and ending with the first child of the node’s child list:

// Create a new XML document. 
var doc = new XML(); 
 
// Create a root node. 
var rootNode = doc.createElement("rootNode"); 
 
// Create three child nodes. 
var oldest = doc.createElement("oldest"); 
var middle = doc.createElement("middle"); 
var youngest = doc.createElement("youngest"); 
 
// Add the rootNode as the root of the XML document tree. 
doc.appendChild(rootNode); 
 
// Add each of the child nodes as children of rootNode. 
rootNode.appendChild(oldest); 
rootNode.appendChild(middle); 
rootNode.appendChild(youngest); 
 
// Use lastChild to iterate through the child nodes of rootNode. 
for (var aNode = rootNode.lastChild; aNode != null; aNode = aNode.previousSibling) { 
    trace(aNode); 
} 
 
/*  
output: 
<youngest /> 
<middle /> 
<oldest /> 
*/

The following example creates a new XML packet and uses the XML.lastChild property to iterate through the child nodes of the root node:

// Create a new XML document. 
var doc = new XML("<rootNode><oldest /><middle /><youngest /></rootNode>"); 
 
var rootNode = doc.firstChild; 
 
// Use lastChild to iterate through the child nodes of rootNode. 
for (var aNode = rootNode.lastChild; aNode != null; aNode=aNode.previousSibling) { 
    trace(aNode); 
} 
/* 
output: 
<youngest /> 
<middle /> 
<oldest /> 
*/

Availability

Flash Media Server 2

Parameters

url

A File object or a URL where the XML document to be loaded is located. If the SWF file that issues this call is running in a web browser, url must be in the same domain as the SWF file. You cannot use a file path for this parameter.

Returns

A boolean value; true if successful; otherwise, false.

Example

The following simple example uses the XML.load() method:

// Create a new XML object. 
var flooring = new XML(); 
 
// Set the ignoreWhite property to true (the default value is false). 
flooring.ignoreWhite = true; 
 
// After loading is complete, trace the XML object. 
flooring.onLoad = function(success) { 
    trace(flooring); 
}; 
 
// Load the XML into the flooring object. 
flooring.load("http://somehttpserver/flooring.xml");

For the contents of the flooring.xml file, and the output that this example produces, see the example for XML.ignoreWhite.

Availability

Flash Media Server 2

Example

The following example uses the XML.loaded property in a simple script:

var my_xml = new XML(); 
my_xml.ignoreWhite = true; 
my_xml.onLoad = function(success) { 
    trace("success: "+success); 
    trace("loaded:"+my_xml.loaded); 
    trace("status:"+my_xml.status); 
}; 
my_xml.load("http://www.flash-mx.com/mm/problems/products.xml");

Information is written to the log file when the onLoad() handler is invoked. If the call completes successfully, the loaded status true is written to the log file, as shown in the following example:

success:true 
loaded:true 
status:0

Availability

Flash Media Server 2

Example

This example uses a SWF file and an XML file located in the same directory. The XML file, named SoapSample.xml, contains the following code:

<?xml version="1.0"?> 
    <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope">  
        <soap:Body xmlns:w="http://www.example.com/weather"> 
            <w:GetTemperature> 
                <w:City>San Francisco</w:City> 
            </w:GetTemperature> 
        </soap:Body> 
    </soap:Envelope>

The source for the SWF file contains the following script (note the comments for the Output strings):

var xmlDoc = new XML() 
xmlDoc.ignoreWhite = true; 
xmlDoc.load("http://www.example.com/SoapSample.xml") 
xmlDoc.onLoad = function(success) { 
    var tempNode = xmlDoc.childNodes[0].childNodes[0].childNodes[0]; 
    trace("w:GetTemperature localname: " + tempNode.localName);  
    // Output: ... GetTemperature 
    var soapEnvNode = xmlDoc.childNodes[0]; 
    trace("soap:Envelope localname: " + soapEnvNode.localName); 
    // Output: ... Envelope 
};

See also

XML.nodeName, XML.prefix

Availability

Flash Media Server 2

Example

The following example shows how the namespaceURI property is affected by the use of prefixes. The XML file used in the example is named SoapSample.xml and contains the following tags:

<?xml version="1.0"?> 
    <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope">  
        <soap:Body xmlns:w="http://www.example.com/weather"> 
            <w:GetTemperature> 
                <w:City>San Francisco</w:City> 
            </w:GetTemperature> 
        </soap:Body> 
    </soap:Envelope>

The source for the Server-Side ActionScript Communication File (ASC file) contains the following script (note the comments for the Output strings). For tempNode, which represents the w:GetTemperature node, the value of namespaceURI is defined in the soap:Body tag. For soapBodyNode, which represents the soap:Body node, the value of namespaceURI is determined by the definition of the soap prefix in the node above it, rather than the definition of the w prefix that the soap:Body node contains.

var xmlDoc = new XML(); 
xmlDoc.load("http://www.example.com/SoapSample.xml"); 
xmlDoc.ignoreWhite = true; 
xmlDoc.onLoad = function(success:Boolean) { 
    var tempNode:XMLNode = xmlDoc.childNodes[0].childNodes[0].childNodes[0]; 
    trace("w:GetTemperature namespaceURI: " + tempNode.namespaceURI);  
    // Output: ... http://www.example.com/weather 
 
    trace("w:GetTemperature soap namespace: " + tempNode.getNamespaceForPrefix("soap"));  
    // Output: ... http://www.w3.org/2001/12/soap-envelope 
 
    var soapBodyNode = xmlDoc.childNodes[0].childNodes[0]; 
    trace("soap:Envelope namespaceURI: " + soapBodyNode.namespaceURI); 
    // Output: ... http://www.w3.org/2001/12/soap-envelope 
}:

The following example uses XML tags without prefixes. It uses a SWF file and an XML file located in the same directory. The XML file, named NoPrefix.xml, contains the following tags:

<?xml version="1.0"?> 
<rootnode>  
    <simplenode xmlns="http://www.w3.org/2001/12/soap-envelope"> 
        <innernode/> 
    </simplenode> 
</rootnode>

The source for the server-side script file contains the following code (note the comments for the Output strings). The rootNode node does not have a default namespace, so its namespaceURI value is an empty string. The simpleNode node defines a default namespace, so its namespaceURI value is the default namespace. The innerNode node does not define a default namespace, but uses the default namespace defined by simpleNode, so its namespaceURI value is the same as that of simpleNode.

var xmlDoc = new XML() 
xmlDoc.load("http://www.example.com/NoPrefix.xml"); 
xmlDoc.ignoreWhite = true; 
xmlDoc.onLoad = function(success) { 
    var rootNode = xmlDoc.childNodes[0]; 
    trace("rootNode Node namespaceURI: " + rootNode.namespaceURI);  
    // Output: [empty string] 
 
    var simpleNode = xmlDoc.childNodes[0].childNodes[0]; 
    trace("simpleNode Node namespaceURI: " + simpleNode.namespaceURI); 
    // Output: ... http://www.w3.org/2001/12/soap-envelope 
 
    var innerNode = xmlDoc.childNodes[0].childNodes[0].childNodes[0]; 
    trace("innerNode Node namespaceURI: " + innerNode.namespaceURI); 
    // Output: ... http://www.w3.org/2001/12/soap-envelope 
};

Availability

Flash Media Server 2

Example

The following example is an excerpt from the example for the XML.firstChild property. It shows how you can use the XML.nextSibling property to loop through an XMLNode object’s child nodes.

for (var aNode = rootNode.firstChild; aNode != null; aNode = aNode.nextSibling) { 
    trace(aNode); 
}

Availability

Flash Media Server 2

Example

The following example creates an element node and a text node, and checks the node name of each:

// Create an XML document. 
var doc = new XML(); 
 
// Create an XML node by using createElement(). 
var myNode = doc.createElement("rootNode"); 
 
// Place the new node into the XML tree. 
doc.appendChild(myNode); 
 
// Create an XML text node by using createTextNode(). 
var myTextNode = doc.createTextNode("textNode"); 
 
// Place the new node into the XML tree. 
myNode.appendChild(myTextNode); 
 
trace(myNode.nodeName); 
trace(myTextNode.nodeName); 
 
/* 
output: 
rootNode 
null 
*/

The following example creates a new XML packet. If the root node has child nodes, the code loops over each child node to display the name and value of the node. Add the following ActionScript to your ASC file:

var my_xml = new XML("<login><username>hank</username><password>rudolph</password></login>"); 
if (my_xml.firstChild.hasChildNodes()) { 
    // Use firstChild to iterate through the child nodes of rootNode. 
    for (var aNode = my_xml.firstChild.firstChild; aNode != null; aNode=aNode.nextSibling) { 
        if (aNode.nodeType == 1) { 
            trace(aNode.nodeName+":\t"+aNode.firstChild.nodeValue); 
        } 
    } 
}

The following node names appear:

username:hank 
password:rudolph

Availability

Flash Media Server 2

Example

The following example creates an element node and a text node and checks the node type of each:

// Create an XML document. 
var doc = new XML(); 
 
// Create an XML node by using createElement(). 
var myNode = doc.createElement("rootNode"); 
 
// Place the new node into the XML tree. 
doc.appendChild(myNode); 
 
// Create an XML text node by using createTextNode(). 
var myTextNode = doc.createTextNode("textNode"); 
 
// Place the new node into the XML tree. 
myNode.appendChild(myTextNode); 
 
trace(myNode.nodeType); 
trace(myTextNode.nodeType); 
 
/* 
output: 
1 
3 
*/

Availability

Flash Media Server 2

Example

The following example creates an element node and a text node and checks the node value of each:

// Create an XML document. 
var doc = new XML(); 
 
// Create an XML node by using createElement(). 
var myNode = doc.createElement("rootNode"); 
 
// Place the new node into the XML tree. 
doc.appendChild(myNode); 
 
// Create an XML text node by using createTextNode(). 
var myTextNode = doc.createTextNode("myTextNode"); 
 
// Place the new node into the XML tree. 
myNode.appendChild(myTextNode); 
 
trace(myNode.nodeValue); 
trace(myTextNode.nodeValue); 
 
/* 
output: 
null 
myTextNode 
*/

The following example creates and parses an XML packet. The code loops through each child node and displays the node value by using the firstChild property and firstChild.nodeValue.

var my_xml = new XML("<login><username>morton</username><password>good&amp;evil</password></login>"); 
trace("using firstChild:"); 
for (var i = 0; i<my_xml.firstChild.childNodes.length; i++) { 
    trace("\t"+my_xml.firstChild.childNodes[i].firstChild); 
} 
trace(""); 
trace("using firstChild.nodeValue:"); 
for (var i = 0; i<my_xml.firstChild.childNodes.length; i++) { 
    trace("\t"+my_xml.firstChild.childNodes[i].firstChild.nodeValue); 
}

The following information is written to the log file:

using firstChild: 
    morton 
    good&evil 
 
using firstChild.nodeValue: 
    morton 
    good&evil

Availability

Flash Media Server 2

Parameters

src

A string or undefined; the raw data, usually in XML format, that is sent by the server.

Example

The following example shows what the XML.onData() event handler looks like by default:

XML.prototype.onData = function (src) { 
    if (src == undefined) { 
        this.onLoad(false); 
    } else { 
        this.parseXML(src); 
        this.loaded = true; 
        this.onLoad(true); 
    } 
};

You can override the XML.onData() event handler to intercept the XML text without parsing it.

Availability

Flash Media Server 2

Parameters

httpStatus

A number; the HTTP status code returned by the server. For example, a value of 404 indicates that the server has not found a match for the requested URI. HTTP status codes can be found in sections 10.4 and 10.5 of the HTTP specification. (For more information, see the W3 website at www.w3.org.)

Example

The following example shows how to use onHTTPStatus() to help with debugging. The example collects HTTP status codes and assigns their value and type to an instance of the XML object. (This example creates the instance members this.httpStatus and this.httpStatusType at runtime.) The onData() handler uses these instance members to trace information about the HTTP response that can be useful in debugging.

var myXml = new XML(); 
 
myXml.onHTTPStatus = function(httpStatus) { 
    this.httpStatus = httpStatus; 
    if(httpStatus < 100) { 
        this.httpStatusType = "flashError"; 
    }  
    else if(httpStatus < 200) { 
        this.httpStatusType = "informational"; 
    } 
    else if(httpStatus < 300) { 
        this.httpStatusType = "successful"; 
    } 
    else if(httpStatus < 400) { 
        this.httpStatusType = "redirection"; 
    } 
    else if(httpStatus < 500) { 
        this.httpStatusType = "clientError"; 
    } 
    else if(httpStatus < 600) { 
        this.httpStatusType = "serverError"; 
    } 
}; 
 
myXml.onData = function(src) { 
    trace(">> " + this.httpStatusType + ": " + this.httpStatus); 
    if(src != undefined) { 
        this.parseXML(src); 
        this.loaded = true; 
        this.onLoad(true); 
    } else { 
        this.onLoad(false); 
    } 
}; 
 
myXml.onLoad = function(success) { 
    // Insert code here. 
} 
 
myXml.load("http://weblogs.macromedia.com/mxna/xml/rss.cfm?query=byMostRecent&languages=1");

See also

LoadVars.onHTTPStatus(), XML.send(), XML.sendAndLoad()

Availability

Flash Media Server 2

Parameters

success

A boolean value; true if the XML object successfully loads with an XML.load() or XML.sendAndLoad() operation; otherwise, false.

Example

The following example includes ActionScript for a simple e-commerce storefront application. The sendAndLoad() method transmits an XML element that contains the user’s name and password and uses an XML.onLoad() handler to process the reply from the server.

var login_str = "<login username=\""+username_txt.text+"\" password=\""+password_txt.text+"\" />"; 
var my_xml = new XML(login_str); 
var myLoginReply_xml = new XML(); 
myLoginReply_xml.ignoreWhite = true; 
myLoginReply_xml.onLoad = function(success){ 
    if (success) { 
        if ((myLoginReply_xml.firstChild.nodeName == "packet") && 
             (myLoginReply_xml.firstChild.attributes.success == "true")) { 
            gotoAndStop("loggedIn"); 
        } else { 
            gotoAndStop("loginFailed"); 
        } 
    } else { 
        gotoAndStop("connectionFailed"); 
    } 
}; 
my_xml.sendAndLoad("http://www.flash-mx.com/mm/login_xml.cfm", myLoginReply_xml);

See also

XML.load(), XML.sendAndLoad()

Availability

Flash Media Server 2

Example

The following example creates an XML packet and writes the parent node of the username node to the log file:

var my_xml = new XML("<login><username>morton</username><password>good&amp;evil</password></login>"); 
 
// The first child is the <login /> node. 
var rootNode = my_xml.firstChild; 
 
// The first child of the root is the <username /> node. 
var targetNode = rootNode.firstChild;  
trace("the parent node of '"+targetNode.nodeName+"' is: "+targetNode.parentNode.nodeName); 
trace("contents of the parent node are:\n"+targetNode.parentNode); 
 
/* output (line breaks added for clarity): 
 
the parent node of 'username' is: login 
contents of the parent node are: 
<login> 
    <username>morton</username> 
    <password>good&amp;evil</password> 
</login> 
 
*/

Availability

Flash Media Server 2

Parameters

source

A string; the XML text to be parsed and passed to the specified XML object.

Returns

A boolean value; true if successful, otherwise, false.

Example

The following example creates and parses an XML packet:

var xml_str = "<state name=\"California\"><city>San Francisco</city></state>" 
 
// Defining the XML source within the XML constructor: 
var my1_xml = new XML(xml_str); 
trace(my1_xml.firstChild.attributes.name); // output: California 
 
// Defining the XML source by using the XML.parseXML method: 
var my2_xml = new XML(); 
my2_xml.parseXML(xml_str); 
trace(my2_xml.firstChild.attributes.name);  
// output: California

Availability

Flash Media Server 2

Example

A directory contains a server-side script file and an XML file. The XML file, named SoapSample.xml, contains the following code:

<?xml version="1.0"?> 
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope">  
<soap:Body xmlns:w="http://www.example.com/weather"> 
<w:GetTemperature> 
<w:City>San Francisco</w:City> 
</w:GetTemperature> 
</soap:Body> 
</soap:Envelope>

The source for the server-side script file contains the following code (note the comments for the Output strings):

var xmlDoc = new XML(); 
xmlDoc.ignoreWhite = true; 
xmlDoc.load("http://www.example.com/SoapSample.xml"); 
xmlDoc.onLoad = function(success) { 
    var tempNode = xmlDoc.childNodes[0].childNodes[0].childNodes[0]; 
    trace("w:GetTemperature prefix: " + tempNode.prefix); // Output: ... w 
    var soapEnvNode = xmlDoc.childNodes[0]; 
    trace("soap:Envelope prefix: " + soapEnvNode.prefix); // Output: ... soap 
};

Availability

Flash Media Server 2

Example

The following example is an excerpt from the example for the XML.lastChild property. It shows how you can use the XML.previousSibling property to loop through an XMLNode object’s child nodes:

for (var aNode = rootNode.lastChild; aNode != null; aNode = aNode.previousSibling) { 
    trace(aNode); 
}

Availability

Flash Media Server 2

Example

The following example creates an XML packet and then deletes the specified XML object and its descendant nodes:

var xml_str = "<state name=\"California\"><city>San Francisco</city></state>"; 
 
var my_xml = new XML(xml_str); 
var cityNode = my_xml.firstChild.firstChild; 
trace("before XML.removeNode():\n"+my_xml); 
cityNode.removeNode(); 
trace("after XML.removeNode():\n"+my_xml); 
 
/* output (line breaks added for clarity): 
before XML.removeNode(): 
<state name="California"> 
<city>San Francisco</city> 
</state> 
 
after XML.removeNode(): 
<state name="California" /> 
*/

Availability

Flash Media Server 2

Returns

A boolean value; true if successful, otherwise, false.

Parameters

url

A string; the destination URL for the specified XML object.

fileObj

A File object, that is not read-only, to which the response is written. If the File object is not open, Flash Media Interactive Server opens the file, writes to it, and closes it. If the File object is open, Flash Media Interactive Server writes to the file and leaves it open. This parameter is optional.

Example

The following example defines an XML packet and sets the content type for the XML object. The data is then sent to a server. The result is written in a File object. It is parsed using a custom parsing function called by the onData handler.

var my_xml = new XML("<highscore><name>Ernie</name><score>13045</score></highscore>"); 
my_xml.contentType = "text/xml"; 
my_xml.send("http://www.flash-mx.com/mm/highscore.cfm", myFile); 
my_xml.onData = function(data) { 
    //custom parsing function 
}

See also

XML.onData()

Availability

Flash Media Server 2

Parameters

url

A string; the destination URL for the specified XML object. If the SWF file issuing this call is running in a web browser the url parameter must be in the same domain as the SWF file.

targetXMLobject

An XML object created with the XML constructor method that will receive the return information from the server.

Returns

A boolean value; true if successful, otherwise, false.

See also

XML.onData()

Availability

Flash Media Server 2

Example

The following example loads an XML packet into a SWF file. A status message indicates whether the XML is loaded and parsed successfully.

var my_xml = new XML(); 
my_xml.onLoad = function(success) { 
    if (success) { 
        if (my_xml.status == 0) { 
            trace("XML was loaded and parsed successfully"); 
        } else { 
            trace("XML was loaded successfully, but was unable to be parsed."); 
        } 
        var errorMessage; 
        switch (my_xml.status) { 
        case 0 : 
            errorMessage = "No error; parse was completed successfully."; 
            break; 
        case -2 : 
            errorMessage = "A CDATA section was not properly terminated."; 
            break; 
        case -3 : 
            errorMessage = "The XML declaration was not properly terminated."; 
            break; 
        case -4 : 
            errorMessage = "The DOCTYPE declaration was not properly terminated."; 
            break; 
        case -5 : 
            errorMessage = "A comment was not properly terminated."; 
            break; 
        case -6 : 
            errorMessage = "An XML element was malformed."; 
            break; 
        case -7 : 
            errorMessage = "Out of memory."; 
            break; 
        case -8 : 
            errorMessage = "An attribute value was not properly terminated."; 
            break; 
        case -9 : 
            errorMessage = "A start tag was not matched with an end tag."; 
            break; 
        case -10 : 
            errorMessage = "An end tag was encountered without a matching 
                start tag."; 
            break; 
        default : 
            errorMessage = "An unknown error has occurred."; 
            break; 
        } 
        trace("status: "+my_xml.status+" ("+errorMessage+")"); 
    } else { 
        trace("Unable to load/parse XML. (status: "+my_xml.status+")"); 
    } 
}; 
my_xml.load("http://www.flash-mx.com/mm/badxml.xml");

Availability

Flash Media Server 2

Returns

A string.

Example

The following example of the XML.toString() method sends <h1>test</h1> to the log file:

var node = new XML("<h1>test</h1>"); 
trace(node.toString());

Availability

Flash Media Server 2

Example

The following example loads an XML file and outputs information about the file:

var my_xml = new XML(); 
my_xml.ignoreWhite = true; 
my_xml.onLoad = function(success){ 
    if (success){ 
        trace("xmlDecl: " + my_xml.xmlDecl); 
        trace("contentType: " + my_xml.contentType); 
        trace("docTypeDecl: " + my_xml.docTypeDecl); 
        trace("packet: " + my_xml.toString()); 
    } 
    else { 
        trace("Unable to load remote XML."); 
    } 
}; 
my_xml.load("http://foo.com/crossdomain.xml");

See also

XML.docTypeDecl, XML.toString()