Erfassen von Texteingaben

Flash Player 9 und höher, Adobe AIR 1.0 und höher

Die Eigenschaft type eines Textfeldes ist standardmäßig auf dynamic festgelegt. Wenn Sie mithilfe der TextFieldType-Klasse für die type -Eigenschaft den Wert input festlegen, können Sie die Benutzereingabe erfassen und den Wert zur Verwendung in anderen Teilen der Anwendung speichern. Eingabetextfelder sind hilfreich bei Formularen und allen Anwendungen, in denen Benutzer einen Textwert für die Verwendung an anderer Stelle im Programm angeben sollen.

Mit dem folgenden Code wird beispielsweise ein Eingabetextfeld mit dem Namen myTextBox erstellt. Wenn der Benutzer Text im Textfeld eingibt, wird das textInput -Ereignis ausgelöst. Eine Ereignisprozedur mit der Bezeichnung textInputCapture erfasst den eingegebenen Textstring und weist diesen String einer Variablen zu. Der neue Text wird in Flash Player oder AIR in einem anderen Textfeld mit dem Namen myOutputBox angezeigt.

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}