Initialisieren von XML-Variablen

Flash Player 9 und höher, Adobe AIR 1.0 und höher

Sie können einem XML-Objekt wie folgt ein XML-Literal zuweisen:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Wie im folgenden Codeauszug dargestellt ist, können Sie auch den new -Konstruktor verwenden, um aus einem String mit XML-Daten eine Instanz eines XML-Objekts zu erstellen:

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Wenn die XML-Daten im String nicht korrekt strukturiert sind (z. B. wenn ein schließendes Tag fehlt), wird ein Laufzeitfehler angezeigt.

Sie können auch Daten als Verweis (aus anderen Variablen) in ein XML-Objekt übergeben, wie im folgenden Beispiel dargestellt ist:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Verwenden Sie die URLLoader-Klasse, um XML-Daten von einer URL zu lesen, wie im folgenden Beispiel dargestellt ist:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Verwenden Sie die XMLSocket-Klasse, um XML-Daten von einer Socketverbindung zu lesen. Weitere Informationen finden Sie im Eintrag zur XMLSocket-Klasse im Handbuch ActionScript 3.0 Reference for the Adobe Flash Platform .